The HPCLUS Procedure

This example uses the iris data set as input to demonstrate how to use PROC HPCLUS to perform cluster analysis. The iris data published by Fisher (1936) have been widely used for examples in discriminant analysis and cluster analysis. The sepal length, sepal width, petal length, and petal width are measured in millimeters on 50 iris specimens from each of three species: Iris setosa, I. versicolor, and I. virginica. Mezzich and Solomon (1980) discuss a variety of cluster analyses of the iris data.

In this example, the HPLUS procedure is used to find three clusters. When the input data set resides on the client and no PERFORMANCE statement is specified, as in the following example, the client performs all computations:

proc hpclus data=sashelp.iris maxclusters=3 outiter outstat=hpclusOutstat1;
   score out=hpclusOut1;
   input SepalLength SepalWidth PetalLength PetalWidth;
   id SepalLength SepalWidth PetalLength PetalWidth Species;
run;

Figure 7 shows the results from the cluster analysis.

In this example, PROC HPCLUS generates the data set hpclusOut1, which contains the cluster membership information for each observation in the input data set. For each observation, the hpclusOut1 data set includes the variables that are specified in the ID statement and two new variables, _CLUSTER_ID_ and _DISTANCE_, which are the ID of the closest cluster and the distance between the observation and the centroid of the closest cluster, respectively. This example uses the variables in both the INPUT statement and the ID statement in order to transfer these variables to the output data set to do further analysis. The following statements extract the first 10 observations from the output data set; they are shown in Figure 8.

proc print noobs data=hpclusOut1(obs=10);
   title1 'First 10 Observations in Output Data Set from PROC HPCLUS';
run;
title1;

The following statements run PROC FREQ with the output data set hpclusOut1 to compare the clusters with the species classification. Figure 9 shows the results.

proc freq data=hpclusOut1;
   tables _CLUSTER_ID_*Species;
run;

PROC HPCLUS creates the output statistics data set, which contains the cluster centroids. This data set includes the iteration number as _ITERATION_, the cluster ID as _CLUSTER_ID_, and the cluster centroids, which consist of the variables that are specified in the INPUT statement. Because the OUTITER option is specified, cluster centroids for each iteration are added to the hpclusOutStat1 data set. The following statements extract the centroids before the first iteration and after the last iteration. Figure 10 and Figure 11 show the results.

proc print noobs data=hpclusOutstat1(firstobs=1 obs=3);
   title2 'Cluster centroids before the first iteration';
run;
title2;


proc print noobs data=hpclusOutstat1(firstobs=13 obs=15);
   title2 'Cluster centroids after the last iteration';
run;
title2;

To plot the clusters, you can use the CANDISC procedure to compute canonical variables and then use the SGPLOT procedure to plot the results as follows:

proc candisc data=hpclusOut1 anova out=can;
   class _CLUSTER_ID_;
   var SepalLength SepalWidth PetalLength PetalWidth;
   title2 'Canonical Discriminant Analysis of Iris Clusters';
run;


proc sgplot data=Can;
   scatter y=Can2 x=Can1 / group=_CLUSTER_ID_ ;
   title3 'Plot of Canonical Variables Identified by Cluster';
run;

Output 5.1.1 shows the plot for clustering.

Output 5.1.1: Graphs for Cluster Analysis