The HP4SCORE Procedure

The following statements run PROC HP4SCORE and compute the misclassification rate of the scored output. Before SAS Enterprise Miner 14.1, the target values from the input data set had to be merged with the predictions in the scored output before fit statistics were computed. This is not necessary with SAS Enterprise Miner 14.1 and later.

filename outmodel "C:\Temp\HPForestModel";
proc HPFOREST data=sampsio.hmeq;
   input CLAge CLNo Loan MortDue Value YoJ DebtInc/level=interval;
   input Bad Delinq Derog nInq Reason/level=nominal;
   target Job/level=nominal;
   ods output FitStatistics=fitstats;
   save file=outmodel;
quit;

Output 3.1.1 shows that the program ran locally and that four threads were used. The default number of threads is the number of processor cores in the computer. The listing also shows the values of the training parameters, the number of observations read (5,960), and the number of observations used in training (5,681). A total of 279 observations are missing the target value and are excluded from training.

Output 3.1.2 shows the baseline fit statistics.

The following statements print the first 10 observations of the table of fit statistics, which are shown in Output 3.1.3. The misclassification rate drops from 0.18835 to 0.02535 as the number of trees in the forest grows from 1 to 10.

proc print data=fitstats(obs=10);
run;

The following statements print the final row of the table of fit statistics, which are shown in Output 3.1.4. The misclassification rate is 0.00334 in the final model.

proc print data=fitstats(firstobs=100);
run;

The following code inputs the model that PROC HPFOREST created and outputs predictions for each observation in the input data set:

proc hp4score data=sampsio.hmeq;
   score file=outmodel out=scoreout3;
run;

Output 3.1.5 shows that PROC HP4SCORE was run with four threads; 5,960 observations were read and output even though 279 of them have a missing target value.

The following code computes the misclassification rate. Note that PROC MEANS excludes the observations that have missing target values.

   data score;
      set scoreout3;
      if upcase(JOB) ne upcase(I_JOB) then misclass=1;
      else misclass=0;
   run;

proc means data=score(where=(JOB ne ''));
   var misclass;
run;

Output 3.1.6 shows the output from PROC MEANS with a misclassification rate of 0.0033445, the same as in the fit statistics table from PROC HPFOREST.