GRADBOOST Procedure

This example uses the GRADBOOST procedure to create a gradient boosting tree model while minimizing the demographic parity for the Job variable. The response variable for the gradient boosting tree model is Bad, a classification variable that has two values (0 for payment of loan and 1 for default). The other variables are predictor variables for the model.

The following statements load the data table mylib.hmeq into your CAS session. For this example, the statements assume that your CAS engine libref is named mylib, but you can substitute any appropriately defined CAS engine libref.

data mylib.hmeq;
   set sampsio.hmeq;
run;

The following statements use PROC GRADBOOST to create a gradient boosting tree model without minimizing the demographic parity:

proc gradboost data=mylib.hmeq nTrees=20 seed=12345;
   input CLAge CLNo DebtInc Derog
         Loan MortDue Value / level=interval;
   input Reason / level=nominal;
   target Bad / level=nominal;
   output out=mylib.scored copyvars=(_ALL_);
   saveState rstore=mylib.model;
run;

The NTREES= option specifies that there are 20 trees to grow in the boosting model. The SEED= option specifies the random number seed for model building to be 12345. The two INPUT statements specify CLAge, CLNo, DebtInc, Derog, Loan, MortDue, Value, and Reason as the input variables. The TARGET statement specifies Bad as the target variable. The OUTPUT statement generates the data table mylib.scored, which contains the predicted mortgage default from the model for each observation and contains all variables from the input data table as copy variables. The SAVESTATE statement creates an analytic store for the model and saves it as a binary object in the data table mylib.model.

Output 17.4.1 displays the fit statistics for the boosting model.

After you train a gradient boosting tree model, you might want to view the demographic parity of the trained model. You can do this by running the ASSESSBIAS procedure. For more information about PROC ASSESSBIAS, see Chapter 3, ASSESSBIAS Procedure.

The following statements use PROC ASSESSBIAS to assess the bias measurements of the model:

proc assessbias data=mylib.scored;
   target bad / event="1" level=nominal;
   var P_Bad1;
   fitstat pvar=P_BAD0 / pevent="0";
   sensitiveVar Job;
run;

Output 17.4.2 displays the bias metric values of the model. PROC ASSESSBIAS also produces other output not shown here.

In order to use the MITIGATEBIAS statement to reduce the demographic parity, you must specify the levels of the response (target) variable and the corresponding predicted variables. You can use the DESCRIBE statement in the ASTORE procedure to obtain this information. The following statements use PROC ASTORE to describe the model:

proc astore;
   describe rstore=mylib.model;
run;

Output 17.4.3 lists the output variables created by the model. The predicted variables are P_BAD1 and P_BAD0. Their corresponding response (target) levels are 1 and 0, respectively.

The following statements use PROC GRADBOOST to create a gradient boosting tree model, while minimizing the demographic parity for Job by using the MITIGATEBIAS statement:

ods graphics on;

proc gradboost data=mylib.hmeq nTrees=20 seed=12345;;
   input CLAge CLNo DebtInc Derog
         Loan MortDue Value / level=interval;
   input Reason / level=nominal;
   target Bad / level=nominal;
   output out=mylib.scored;
   saveState rstore=mylib.model;
   mitigateBias pevents="1 0"
                pvars=(P_BAD1 P_BAD0)
                seed=12345
                sensitivevar=Job
                targetEvent="1"
                maxiter=11;
run;

The PEVENTS= option lists the levels of the response (target) variable Bad. The predicted variables correspond to the levels that are listed in the PVARS= option. The PVARS= option lists the predicted variables that contain the posterior probability for each level in model prediction that corresponds to the response (target) variable Bad. The SEED= option specifies the seed for the pseudorandom number generator to be 12345. The SENSITIVEVAR= option names the variable Job as the sensitive variable for the purpose of reducing the value of the bias measurement. The TARGETEVENT= option specifies the value 1 as the event of interest. The MAXITER= option specifies 11 as the maximum number of iterations for the EGR algorithm.

Output 17.4.4 displays the information about the options that are used for bias mitigation. Output 17.4.5 displays the model accuracy and bias metric values over each iteration of the EGR algorithm. Output 17.4.6 shows the iteration history, which is a graphical representation of the iteration history table. The graph displays the bias metric and the misclassification rate for each iteration. PROC GRADBOOST selects the iteration that has the lowest bias metric. In this case, the 10th iteration is selected; the graph indicates this selection by using the legend and a vertical line. The MITIGATEBIAS statement also creates other tables, which are not shown here but are listed in the section ODS Table Names.