Time Series Model Package

The airline passenger data, given as Series G in Box and Jenkins (1976), have been used in time series analysis literature as an example of a nonstationary seasonal time series; for more information about ARIMA modeling of Series G, see "Example 7.2 Seasonal Model for the Airline Series" in the ARIMA chapter of SAS/ETS User's Guide.

This example shows how you can use the objects in the TSM package to fit the airline model, ARIMA(0,1,1) (0,1,1) NOINT and to fit the Winters exponential smoothing model to the airline series. In particular, it shows how you can do the following:

The broad outline of the code in this example is as follows:

proc tsmodel data=mylib.air
             outobj=(airFor=mylib.airFor airEst=mylib.airEst)
             outscalar=mylib.nbetter outarray=mylib.out lead=12;
   id date interval=month;
   var air;
   outarrays esmErr airErr;   **Store residuals of ESM and ARIMA models;
   outscalars nbetter nfor;
   require tsm;
   submit;

      **Temporary work arrays used in ARIMA spec;
      array diff[2]/nosymbols;
      array ma[1]/nosymbols;

      *** Analysis based on the airline model ***;
      declare object airModel(tsm);
      declare object airSpec(arimaspec);

      **Set up the airline model spec:*;
      ** Model: log(air) ~ (0,1,1)(0,1,1)12 noint *;
      rc = airSpec.Open( );
      *** Specify differencing orders ***;
      diff[1] = 1;
      diff[2] = 12;
      rc = airSpec.SetDiff(diff,2);
      *** Specify moving average orders: q = (1)(12)  ***;
      *** Use AddMAPoly twice  for the two factors    ***;
      ma[1] = 1;
      rc = airSpec.AddMAPoly(ma);
      ma[1] = 12;
      rc = airSpec.AddMAPoly(ma);
      *** Specify NOINT             ***;
      rc = airSpec.SetOption('noint',1);
      *** Specify the log transform     ***;
      rc = airSpec.SetTransform('log');
      *** Done setting up the ARIMA model ***;
      rc = airSpec.Close( );

      *** Set up and run the airModel TSM object ***;
      rc = airModel.Initialize(airSpec);
      rc = airModel.SetY(Air);
      rc = airModel.SetOption('lead',12);
      rc = airModel.Run( );

      *** Output the airline model forecasts and estimates ***;
      declare object airFor(tsmfor);
      declare object airEst(tsmpest);
      rc = airFor.Collect(airModel);
      rc = airEst.Collect(airModel);

      ***Put the airline model residuals in airErr array;
      rc = airModel.getForecast('error',airErr);

      *** Analysis based on ESM model ***;
      declare object esmModel(tsm);
      declare object esmSpec(esmspec);
      rc = esmSpec.open( );
      rc = esmSpec.SetOption('method', 'winters');
      rc = esmSpec.close( );

      ***Set up and run the TSM object ***;
      rc = esmModel.Initialize(esmspec);
      rc = esmModel.SetY(Air);
      rc = esmModel.SetOption('lead',12);
      rc = esmModel.Run( );

      **Put the ESM model residuals in esmErr array;
      rc = esmModel.getForecast('error',esmErr);

      ***Compute an ad hoc statistic based on airErr and esmErr arrays;
      nbetter = 0;
      nfor = esmModel.nfor( );
      do t=1 to nfor;
         if airErr[t] ^= . & esmErr[t] ^= . then do;
            if abs(airErr[t]) < abs(esmErr[t])
               then nbetter = nbetter + 1;
         end;
      end;
   endsubmit;
  quit;

Output 32.1.1 shows the predictions, and Output 32.1.2 shows the parameter estimates for the airline model.

Output 32.1.3 shows the number of times the airline model residuals are smaller than the Winters model residuals.