SASEBLS Interface Engine

This example shows how to retrieve data from the Business Employment Dynamics Statistics survey. You can view these data by using the following URL:

https://www.bls.gov/bdm/data.htm

INSERIES is an input SAS data set that lists the IDs of the time series to be retrieved from the Business Employment Dynamics Statistics (BDM) database. In this example, the input SAS data set is named in the INSET=INSERIES option. To create the INSERIES data set, use the DATA step. In the DATA statement, the name of the input data set is specified as 'INSERIES'. Next, the length of the series ID is specified as 32 bytes prior to listing the ID of each series to be accessed. Each time series is listed on its own line, along with the OUTPUT statement. When the series IDs have been listed, the DATA step is ended with a RUN statement. The following SASEBLS LIBNAME statement specifies the libref (BLS), followed by the engine name (SASEBLS) and the physical path where the retrieved BLS data are to be stored. The OUTJSON= option names the file where the JSON data are stored. The output data set is created using the OUTJSON= option and placed in the folder that is specified in the SASEBLS LIBNAME statement. The INSET= option specifies the INSERIES data set for the list of series to retrieve using their IDs. In this example, four time series are requested, along with any calculations.

The date range of the data starts with 2019, as specified by the STARTYEAR= option. The ENDYEAR= option specifies the last year, 2020, to include in the range of data to retrieve. The FREQ=QUARTERLY (or FREQ=Q) option specifies the selection of quarterly data, but because the CALCULATIONS=TRUE option is specified, the retrieved data also include the net change calculation and percentage change calculation statistics. The FORMAT= option specifies that the data are to be retrieved using the JSON format. Output 23.10.1 shows the data that are retrieved. Output 23.10.2 shows the catalog information for the retrieved data.

options validvarname=any;
libname blscat "%sysget(BLS)";     /* for Catalog data set*/

DATA inseries;
   length seriesid $ 32;
   seriesid = 'BDS0000000000100030110004LQ5'; output;
   seriesid = 'BDS0000000000200050110001LQ5'; output;
   seriesid = 'BDS0000000000100000110001LQ5'; output;
   seriesid = 'BDS0000000000200000110001LQ5'; output;
RUN;

title 'Retrieve Business Employment Dynamics Statistics Data';
libname bls sasebls "%sysget(BLS)"
   USER='XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX'
   SETNAME=BDM
   INSET=inseries
   PAYPATH= "%sysget(BLS)payload"
   OUTJSON=blsex10
   STARTYEAR='2019'
   ENDYEAR='2020'
   FREQ=Quarterly
   CALCULATIONS=true
   CATALOG=true
   FORMAT=json;

data myBDM;
   set bls.blsex10;
run;

proc contents data=myBDM; run;
proc print data=myBDM; run;

The following statements print the catalog data shown in Output 23.10.2:

libname blscat "%sysget(BLS)";

data myCAT;
   set blscat.blsex10_catalog;
run;

proc print data=myCat; run;