SASEBLS Interface Engine

This example shows how to retrieve data from the Quarterly Census of Employment and Wages surveys. You can view these data by using the following URL:

https://www.bls.gov/cew/data-overview.htm

INSERIES is an input SAS data set that lists the IDs of the time series to be retrieved from the Quarterly Census of Employment and Wages (QCEW) database. In this example, the input SAS data set is named in the INSET=INSERIES option. To create the INSERIES data set, use the DATA step. In the DATA statement, the name of the input data set is specified as 'INSERIES'. Next, the length of the series ID is specified as 32 bytes prior to listing the ID of each series to be accessed. Each time series is listed on its own line, along with the OUTPUT statement. When the series IDs have been listed, the DATA step is ended with a RUN statement. The following SASEBLS LIBNAME statement specifies the libref (BLS), followed by the engine name (SASEBLS) and the physical path where the retrieved BLS data are to be stored. The OUTJSON= option names the file where the JSON data are stored. The output data set is created using the OUTJSON= option and placed in the folder that is specified in the SASEBLS LIBNAME statement. The INSET= option specifies the INSERIES data set for the list of series to retrieve using their IDs. In this example, four time series are requested, along with any calculations.

The date range of the data starts with 2019, as specified by the STARTYEAR= option. The ENDYEAR= option specifies the last year, 2020, to include in the range of data to retrieve. The FREQ=MONTH option specifies the selection of monthly data, but because the CALCULATIONS=TRUE option is specified, the retrieved data also include the net change calculation and percentage change calculation statistics. No catalog is available for the selected QCEW data in this example, so the description of each time series can be obtained by using the series ID format described at the following URL:

https://www.bls.gov/help/hlpforma.htm#EN

These descriptions can be placed in the label for each time series, as shown in the LABEL statements in the myQCEW DATA step.

The FORMAT= option specifies that the data are to be retrieved using the JSON format. Output 23.9.1 shows the data that are retrieved.

options validvarname=any;

DATA inseries;
   length seriesid $ 32;
   seriesid = 'ENU0603710010'; output;  /* Los Angeles County */
   seriesid = 'ENU0607310010'; output;  /* San Diego County */
RUN;

title 'Retrieve State and County Employment and Wages Data';
libname bls sasebls "%sysget(BLS)"
   USER='XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX'
   SETNAME=QCEW
   INSET=inseries
   PAYPATH= "%sysget(BLS)payload"
   OUTJSON=blsex09
   STARTYEAR='2019'
   ENDYEAR='2020'
   FREQ=Month
   CALCULATIONS=true
   FORMAT=json;

data myQCEW;
   set bls.blsex09;
   label ENU0603710010=
      'All employees, industries, and establishment sizes in Los Angeles County, NSA';
   label ENU0607310010=
      'All employees, industries, and establishment sizes in San Diego County, NSA';
run;

proc contents data=myQCEW; run;
proc print data=myQCEW; run;