SASEBLS Interface Engine

This example shows how to retrieve data from the Job Openings and Labor Turnover Surveys, JT and JL. You can view these data by using the following URL:

https://www.bls.gov/jlt

INSERIES is an input SAS data set that lists the IDs of the time series to be retrieved from the Job Openings and Labor Turnover Statistics database. In this example, the input SAS data set is named in the INSET=INSERIES option. To create the INSERIES data set, use the DATA step. In the DATA statement, the name of the input data set is specified as 'INSERIES'. Next, the length of the series ID is specified as 32 bytes prior to listing the ID of each series to be accessed. Each time series is listed on its own line, along with the OUTPUT statement. When the series IDs have been listed, the DATA step is ended with a RUN statement. The following SASEBLS LIBNAME statement specifies the libref (BLS), followed by the engine name (SASEBLS) and the physical path where the retrieved BLS data are to be stored. The OUTJSON= option names the file where the JSON data are stored. The output data set is created using the OUTJSON= option and placed in the folder that is specified in the SASEBLS LIBNAME statement. The INSET= option specifies the INSERIES data set for the list of series to retrieve using their IDs. In this example, four time series are requested, along with any calculations.

The date range of the data starts with 2002, as specified by the STARTYEAR= option. The ENDYEAR= option specifies the last year, 2003, to include in the range of data to retrieve. The FREQ=MONTH option specifies the selection of monthly data, but because the CALCULATIONS=TRUE option is specified, the retrieved data also include the net change calculation and percentage change calculation statistics. There is no catalog for the JOLT data set, so the description of each statistical time series can be obtained by the seriesid format described at the following URL:

https://www.bls.gov/help/hlpforma.htm#jt

These descriptions can be placed in the label for each time series as shown in the label statements of the myJOLT DATA STEP.

The FORMAT= option specifies that the data are to be retrieved using the JSON format. For brevity, only the first four observations are shown in Output 23.8.1.

options validvarname=any;

DATA inseries;
   length seriesid $ 32;
   seriesid = 'JLU000000MWHIL'; output;  /* Total Nonfarm Hires (SIC based) */
   seriesid = 'JLU91000000TSR'; output;  /* Federal Total Separations (SIC based)*/
   seriesid = 'JTS000000000000000HIL'; output; /* Total Nonfarm Hires */
   seriesid = 'JTU929000000000000LDL'; output; /* Govt. Layoffs and Discharges */
RUN;

title 'Retrieve Job Openings and Labor Turnover Statistics Data';
libname bls sasebls "%sysget(BLS)"
   USER='XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX'
   SETNAME=JOLT
   INSET=inseries
   PAYPATH= "%sysget(BLS)payload"
   OUTJSON=blsex08
   STARTYEAR='2002'
   ENDYEAR='2003'
   FREQ=Month
   CALCULATIONS=true
   FORMAT=json;

data myJOLT;
   set bls.blsex08 ;
   label JLU000000MWHIL='Total Nonfarm Hires (SIC based)';
   label JLU91000000TSR='Federal Total Separations (SIC based)';
   label JTS000000000000000HIL='Total Nonfarm Hires';
   label JTU929000000000000LDL='State and Local Government Layoffs and Discharges';
run;

proc contents data=myJOLT; run;
proc print data=myJOLT(obs=4); run;