HMM Procedure

Cross-sectional time series data consist of observations over both time and many subjects (such as individuals, objects, firms, or geographical areas). Let , where and , denote a p-dimensional vector of random variables at the tth position in the nth section, where is the sample size of the nth section. The follows the Gaussian HMM; that is,

where and are mean and covariance parameters, respectively, whose values depend on the state variable . follows the first-order Markov chain; that is,

where denotes the conditional probability. is independent of any and . The range of is a finite set, . The transition probability from state i to state j is expressed as

The matrix is called the transition probability matrix (TPM). The initial state probability vector (ISPV), , of the first state is

The Gaussian HMM for cross-sectional time series data, which is the same as the Gaussian HMM for time series data, can be described as , where , which consists of parameters that define the state-dependent distribution of observable variables.

Consider a univariate six-state Gaussian HMM that has the following parameter values:

The following statements simulate the 10,000-section time series from the previous model to provide test data for the HMM procedure:

%let nSections = 10000;
%let T = 100;
%let seed = 1234;
%let nStates = 6;
%let mu1 = 0;
%let sigma1 = 0.0625;
%let mu2 = 0;
%let sigma2 = 0.25;
%let mu3 = 0;
%let sigma3 = 1;
%let mu4 = 0;
%let sigma4 = 4;
%let mu5 = 0;
%let sigma5 = 16;
%let mu6 = 0;
%let sigma6 = 64;
%let selfTransProb = 0.95;

%macro createCstsTable(tableName);
   data &tableName.;
      do sec = 1 to &nSections.;
         state = ceil(uniform(&seed.)*&nStates.);
         do t = 1 to &T.;
            %do i = 1 %to &nStates.;
               if(state=&i.) then do;
                  y = &&mu&i.. + sqrt(&&sigma&i..)*normal(&seed.);
                  output;
               end;
            %end;
            u = uniform(&seed.);
            if(u>&selfTransProb.) then do;
               u = (u-&selfTransProb.)/(1-&selfTransProb.)*(&nStates.-1);
               state=state + ceil(u);
               if(state>&nStates.) then state = state - &nStates.;
            end;
         end;
      end;
   run;
%mend;

%createCstsTable(cstsDGP);

data mylib.cstsDGP;
   set cstsDGP;
run;

The following statements estimate the Gaussian HMM:

proc hmm data=mylib.cstsDGP
   outstat=mylib.cstsStat;
   id section=sec time=t;
   model y  / method=ml type=gaussian nstate=6;
   optimize ALGORITHM=activeset printlevel=3 printIterFreq=1;
   estimate out=mylib.cstsEst;
   evaluate out=mylib.cstsEval;
   decode out=mylib.cstsDecode;
   filter out=mylib.cstsFilter;
   smooth out=mylib.cstsSmooth;
   forecast out=mylib.cstsForcast;
   score outmodel=mylib.cstsModel;
run;

The estimates of the ISPV, TPM, mean parameters, and covariance parameters are shown in Figure 18, Figure 19, Figure 20, and Figure 21, respectively. They are all very close to the true parameters that are used in the data generating process.