CQLIM Procedure

This example uses the CQLIM procedure to process a large data table.

The following DATA step generates a data set that contains 5 million observations from a censored model. The model contains seven variables.

data simulate;
   call streaminit(12345);
   array vars x1-x7;
   array parms{7}  (3 4 2 4 -3 -5 -3);
   intercept = 2;
   do i = 1 to 5000000;
      sum_xb = 0;
      do j = 1 to 7;
         vars[j] = rand('NORMAL', 0, 1);
         sum_xb = sum_xb + parms[j] * vars[j];
      end;
      y = intercept + sum_xb + 100 * rand('NORMAL', 0, 1);
      if y > 400 then y = 400;
      if y < 0   then y = 0;
      output;
   end;
keep y x1-x7;
run;

You can load the data set simulate into a data table in your session that is associated with the mylib libref. The DATA step assumes that your libref is named mylib, but you can substitute any appropriately defined libref.

data mylib.simulate;
   set simulate;
run;

The following statements estimate a censored model:

proc cqlim data = mylib.simulate;
   model y = x1-x7 / censored(lb = 0 ub = 400);
run;

Output 12.1.1 shows the estimation results for the censored model. The "Model Fit Summary" table shows detailed information about the model. All parameter estimates in the "Parameter Estimates" table are highly significant and correspond to their theoretical values that were set during the data generating process.