Network Action Set

This section contains PROC CAS code.

Note: Input data must be accessible in your CAS session, either as a CAS table or as a transient-scope table. A CAS table has a two-level name: the first level is your CAS engine libref, and the second level is the table name. You refer to this table in the CAS procedure by specifying only the second level. For more information about two-level names, see Chapter 2, Shared Concepts (SAS Viya: Machine Learning Procedures). A transient-scope table is called directly from the action and exists in memory for the duration of the action. For more information about accessing data, see SAS Viya: System Programming Guide. For more information about PROC CAS and programming in CASL, see SAS Cloud Analytic Services: CASL Programmer’s Guide and SAS Cloud Analytic Services: CASL Reference.

This example illustrates the use of the shortest path algorithm for all source-sink pairs on the undirected graph G shown in Figure 20.

Figure 20: An Undirected Graph G

The undirected graph G can be represented by the following links data set, LinkSetIn:

data LinkSetIn;
   input from $ to $ weight @@;
   datalines;
A B 3  A C 2  A D 6  A E 4  B D 5
B F 5  C E 1  D E 2  D F 1  E F 4
;

The following DATA step loads the LinkSetIn data set into a CAS data table named mycas.LinkSetIn. These statements assume that the CAS engine libref is named mycas, but you can substitute any appropriately defined CAS engine libref.

data mycas.LinkSetIn;
   set LinkSetIn;
run;

The following statements find the shortest paths for all source-sink pairs:

proc cas;
   loadactionset "network";
   action network.shortestPath result=r status=s /
      indexOffset = 1
      links       = {name = "LinkSetIn"}
      outWeights  = {name = "ShortPathW", replace=true}
      outPaths    = {name = "ShortPathP", replace=true};
   run;
   print r.ProblemSummary; run;
   print r.SolutionSummary; run;
   action table.fetch / table  = "ShortPathP" to=1000
                        sortBy = {"source","sink","order"}; run;
   action table.fetch / table = "ShortPathW" to=1000
                        sortBy = {"source","sink","path_weight"}; run;
quit;

The problem summary output from this action is shown in Output 28.17.1.

The solution summary output from this action is shown in Output 28.17.2.

The output data table ShortPathP contains the shortest paths, as shown in Output 28.17.3.

The output data table ShortPathW contains the path weights of the shortest paths of each source-sink pair, as shown in Output 28.17.4.