Network Action Set

This section contains PROC CAS code.

Note: Input data must be accessible in your CAS session, either as a CAS table or as a transient-scope table. A CAS table has a two-level name: the first level is your CAS engine libref, and the second level is the table name. You refer to this table in the CAS procedure by specifying only the second level. For more information about two-level names, see Chapter 2, Shared Concepts (SAS Viya: Machine Learning Procedures). A transient-scope table is called directly from the action and exists in memory for the duration of the action. For more information about accessing data, see SAS Viya: System Programming Guide. For more information about PROC CAS and programming in CASL, see SAS Cloud Analytic Services: CASL Programmer’s Guide and SAS Cloud Analytic Services: CASL Reference.

This section provides an example of using the path enumeration algorithm on the directed graph G shown in Figure 11 to find all paths between one source-sink pair by using the SOURCE= and SINK= options.

The directed graph G can be represented by the following links data set, LinkSetIn:

data LinkSetIn;
   input from $ to $ weight @@;
   datalines;
A B 1 A E 1 B C 1 C A 6 C D 1
D E 3 D F 1 E B 1 E C 4 F E 1
E A 1
;

The following DATA step loads the LinkSetIn data set into a CAS data table named mycas.LinkSetIn. These statements assume that the CAS engine libref is named mycas, but you can substitute any appropriately defined CAS engine libref.

data mycas.LinkSetIn;
   set LinkSetIn;
run;

The following statements find all paths between node D and node A whose path link weight is less than or equal to 10. They output the results in the data tables PathLinks and PathNodes.

proc cas;
   loadactionset "network";
   action network.path result=r status=s /
      indexOffset   = 1
      direction     = "directed"
      links         = {name = "LinkSetIn"}
      source        = "D"
      sink          = "A"
      maxLinkWeight = 10
      outPathsLinks = {name = "PathLinks", replace=true}
      outPathsNodes = {name = "PathNodes", replace=true};
   run;
   print r.ProblemSummary; run;
   print r.SolutionSummary; run;
   action table.fetch / table = "PathLinks" to=1000
                        sortBy = {"source","sink","path","order"}; run;
   action table.fetch / table = "PathNodes" to=1000
                        sortBy = {"source","sink","path","order"}; run;
quit;

The problem summary output from this action is shown in Output 28.11.1.

The solution summary output from this action is shown in Output 28.11.2.

The output data table PathLinks contains the links of the three paths from D to A whose path link weight is less than or equal to 10, as shown in Output 28.11.3.

The output data table PathNodes contains the nodes of the three paths, as shown in Output 28.11.4.

The three (short) paths are shown graphically in Output 28.11.5.

s:loadtable{casLib="casuser", path="LinkSetIn.csv"}

s:network_path{
   indexOffset   = 1,
   direction     = "directed",
   links         = {name = "LinkSetIn"},
   source        = "D",
   sink          = "A",
   maxLinkWeight = 10,
   outPathsLinks = {name = "PathLinks", replace=true},
   outPathsNodes = {name = "PathNodes", replace=true}}

s.upload_file('LinkSetIn.csv')

s.network.path(
    indexOffset   = 1,
    direction     = "directed",
    links         = {"name": "LinkSetIn"},
    source        = "D",
    sink          = "A",
    maxLinkWeight = 10,
    outPathsLinks = {"name": "PathLinks", "replace": True},
    outPathsNodes = {"name": "PathNodes", "replace": True})