Network Action Set

This section contains PROC CAS code.

Note: Input data must be accessible in your CAS session, either as one or more CAS tables or as one or more transient-scope tables. A CAS table has a two-level name: the first level is your CAS engine libref, and the second level is the table name. You refer to this table in the CAS procedure by specifying only the second level. For more information about two-level names, see Chapter 2, Shared Concepts (SAS Viya: Machine Learning Procedures). A transient-scope table is called directly from the action and exists in memory for the duration of the action. For more information about accessing data, see SAS Viya: System Programming Guide. For more information about PROC CAS and programming in CASL, see SAS Cloud Analytic Services: CASL Programmer’s Guide and SAS Cloud Analytic Services: CASL Reference.

This example illustrates the use of the core decomposition algorithm on the undirected graph G shown in Figure 7.

Figure 7: An Undirected Graph

The undirected graph G can be represented using the following nodes data set, NodeSetIn, and links data set, LinkSetIn:

data NodeSetIn;
   input node $ @@;
   datalines;
v1    v2   v3   v4   v5
v6    v7   v8   v9  v10
v11  v12  v13  v14  v15
v16  v17  v18  v19
;

data LinkSetIn;
   input from $ to $ @@;
   datalines;
v1   v2   v5  v6   v6  v7   v7  v8  v10 v11
v2   v3   v3  v4   v2  v4   v8  v9   v9 v10
v8  v18  v10 v12  v13 v14  v13 v15  v13 v16
v13 v17  v14 v15  v14 v16  v14 v17  v15 v16
v15 v17  v16 v17  v18 v13  v18 v17  v18 v16
v12 v14  v12 v15  v12 v16
;

The following DATA steps load the NodeSetIn and LinkSetIn data sets into CAS data tables named mycas.NodeSetIn and mycas.LinkSetIn. These statements assume that the CAS engine libref is named mycas, but you can substitute any appropriately defined CAS engine libref.

data mycas.NodeSetIn;
   set NodeSetIn;
run;
data mycas.LinkSetIn;
   set LinkSetIn;
run;

The following statements calculate the core decomposition and output the results in the data table NodeSetOut:

proc cas;
   loadactionset "network";
   action network.core result=r status=s /
      links    = {name = "LinkSetIn"}
      nodes    = {name = "NodeSetIn"}
      outNodes = {name = "NodeSetOut", replace=true};
   run;
   print r.ProblemSummary; run;
   print r.SolutionSummary; run;
   action table.fetch / table = "NodeSetOut" sortBy = "core_out"; run;
quit;

The problem summary output from this action is shown in Output 28.7.1.

The solution summary output from this action is shown in Output 28.7.2.

The nodes output data table NodeSetOut contains the core number (variable core_out) for each node, as shown in Output 28.7.3.

Figure 8 shows the graph layered by its core number.

Figure 8: Core Decomposition