Network Action Set

This section contains PROC CAS code.

Note: Input data must be accessible in your CAS session, either as one or more CAS tables or as one or more transient-scope tables. A CAS table has a two-level name: the first level is your CAS engine libref, and the second level is the table name. You refer to this table in the CAS procedure by specifying only the second level. For more information about two-level names, see Chapter 2, Shared Concepts (SAS Viya: Machine Learning Procedures). A transient-scope table is called directly from the action and exists in memory for the duration of the action. For more information about accessing data, see SAS Viya: System Programming Guide. For more information about PROC CAS and programming in CASL, see SAS Cloud Analytic Services: CASL Programmer’s Guide and SAS Cloud Analytic Services: CASL Reference.

This example illustrates the use of the connectedComponents action on the undirected graph G shown in Figure 6.

Figure 6: An Undirected Graph G

You can represent the directed graph G by using the following nodes data set, NodeSetIn, and links data set, LinkSetIn:

data NodeSetIn;
  input node $;
  datalines;
J
;
data LinkSetIn;
   input from $ to $ @@;
   datalines;
A B  A C  B C  C H  D E  D F  D G  F E  G I  K L
;

The following DATA steps load the NodeSetIn and LinkSetIn data sets into CAS data tables named mycas.NodeSetIn and mycas.LinkSetIn. These statements assume that the CAS engine libref is named mycas, but you can substitute any appropriately defined CAS engine libref.

data mycas.NodeSetIn;
   set NodeSetIn;
run;
data mycas.LinkSetIn;
   set LinkSetIn;
run;

The following statements find the connected components and output the results in the data table NodeSetOut:

proc cas;
   loadactionset "network";
   action network.connectedComponents result=r status=s /
      indexOffset = 1
      nodes       = {name = "NodeSetIn"}
      links       = {name = "LinkSetIn"}
      outNodes    = {name = "NodeSetOut", replace=true};
   run;
   print r.ProblemSummary; run;
   print r.SolutionSummary; run;
   action table.fetch / table = "NodeSetOut" sortBy = "concomp"; run;
quit;

The problem summary output from this action is shown in Output 28.6.1.

The solution summary output from this action is shown in Output 28.6.2.

The output data table NodeSetOut contains the connected components of the input graph, as shown in Output 28.6.3.