Network Action Set

This section contains PROC CAS code.

Note: Input data must be accessible in your CAS session, either as a CAS table or as a transient-scope table. A CAS table has a two-level name: the first level is your CAS engine libref, and the second level is the table name. You refer to this table in the CAS procedure by specifying only the second level. For more information about two-level names, see Chapter 2, Shared Concepts (SAS Viya: Machine Learning Procedures). A transient-scope table is called directly from the action and exists in memory for the duration of the action. For more information about accessing data, see SAS Viya: System Programming Guide. For more information about PROC CAS and programming in CASL, see SAS Cloud Analytic Services: CASL Programmer’s Guide and SAS Cloud Analytic Services: CASL Reference.

This example illustrates the use of the biconnected components algorithm on the undirected graph G shown in Figure 1.

The undirected graph G can be represented by the following links data set, LinkSetIn:

data LinkSetIn;
   input from $ to $ @@;
   datalines;
A B  A F  A G  B C  B D
B E  C D  E F  G I  G H
H I
;

The following DATA step loads the LinkSetIn data set into a CAS data table named mycas.LinkSetIn. These statements assume that the CAS engine libref is named mycas, but you can substitute any appropriately defined CAS engine libref.

data mycas.LinkSetIn;
   set LinkSetIn;
run;

The following statements calculate the biconnected components and articulation points for G and output the results in the data tables LinkSetOut and NodeSetOut:

proc cas;
   loadactionset "network";
   action network.biconnectedComponents result=r status=s /
      indexOffset = 1
      links       = {name = "LinkSetIn"}
      outNodes    = {name = "NodeSetOut", replace="true"}
      outLinks    = {name = "LinkSetOut", replace="true"};
   run;
   print r.ProblemSummary; run;
   print r.SolutionSummary; run;
   action table.fetch / table = "LinkSetOut" sortBy = {"biconcomp","from","to"}; run;
   action table.fetch / table = "NodeSetOut" sortBy = "node"; run;
quit;

The problem summary output from this action is shown in Output 28.1.1.

The solution summary output from this action is shown in Output 28.1.2.

The output data table LinkSetOut contains the biconnected components of the input graph, as shown in Output 28.1.3.

The output data table NodeSetOut contains the articulation points of the input graph, as shown in Output 28.1.4.

The biconnected components are shown graphically in Output 28.1.5 and Output 28.1.6.

s:loadtable{casLib="casuser", path="LinkSetIn.csv"}

s:network_biconnectedComponents{
   indexOffset = 1,
   links       = {name = "LinkSetIn"},
   outNodes    = {name = "NodeSetOut", replace=true},
   outLinks    = {name = "LinkSetOut", replace=true}}

s.upload_file('LinkSetIn.csv')

s.network.biconnectedComponents(
    indexOffset = 1,
    links       = {"name":"LinkSetIn"},
    outNodes    = {"name":"NodeSetOut", "replace":True},
    outLinks    = {"name":"LinkSetOut", "replace":True})