Autotune Action Set

This section contains PROC CAS code.

Note: Input data must be accessible in your CAS session, either as a CAS table or as a transient-scope table. A CAS table has a two-level name: the first level is your CAS engine libref, and the second level is the table name. You refer to this table in the CAS procedure by specifying only the second level. For more information about two-level names, see Chapter 2, Shared Concepts (SAS Viya: Machine Learning Procedures). A transient-scope table is called directly from the action and exists in memory for the duration of the action. For more information about accessing data, see SAS Viya: System Programming Guide. For more information about PROC CAS and programming in CASL, see SAS Cloud Analytic Services: CASL Programmer’s Guide and SAS Cloud Analytic Services: CASL Reference.

This example illustrates the use of the tuneTsne action to automatically tune the hyperparameters for t-distributed stochastic neighbor embedding. The following DATA step loads the iris data set from the Sashelp library into a data table named mycas.iris. These statements assume that the CAS engine libref is named mycas, but you can substitute any appropriately defined CAS engine libref.

  data mycas.iris;
     set sashelp.iris;
     id=_n_;
  run;

The following PROC CAS code uses the tuneTsne action to automatically tune the hyperparameters of a two-dimensional embedding of the Iris data. Note that the syntax of the trainOptions parameter here is the same as the syntax of the tSne action. For more information about the tSne action, see Chapter 40, t-Distributed Stochastic Neighbor Embedding Action Set.

  proc cas noqueue;
     action autotune.tuneTsne /
        trainOptions     = {
           table         = {name='iris'},
           inputs        = {"SepalLength", "SepalWidth", "PetalLength", "PetalWidth"},
           nDimensions   = 2,
           perplexity    = 5,
           learningRate  = 100,
           maxIters      = 500,
           output        = {casOut={name="tsne_out", replace="TRUE"},
                            copyvars={"id", "species"}}
        },
        tunerOptions     = {
           searchMethod  = "GA",
           popSize       = 10,
           logLevel      = 3,
           seed          = 12345
        }
        /* Tuning Parameters

           You do not need to specify any tuning parameters for the default
           tuning process. If you want to make adjustments to the default
           tuning process, uncomment the following block of code and change
           any of the tuning parameters' attributes.

        , tuningParameters = {
           {name="perplexity",   initValue=30,   lb=5,    ub=50,   exclude=false},
           {name="learningRate", initValue=1000, lb=10,   ub=2000, exclude=false},
           {name="maxIters",     initValue=300,  lb=250,  ub=5000, exclude=false}
       }
       */
     ;
     ods output TunerResults      = TuneResults(keep=tSNEKLLoss);
     ods output EvaluationHistory = EvalHistory;
     ods output IterationHistory  = IterHistory;
     run;
  quit;

The following optional code includes two DATA steps and two SGPLOT procedure steps that generate the following two plots from the tuneTsne action results:

 data _null_;
    set TuneResults;
    if _n_ = 1 then call symput('default', tSNEKLLoss);
    else if _n_ = 2 then call symput('best', tSNEKLLoss);
 run;

 data EvalHistory;
    set EvalHistory;
    default = &default.;
    best = &best.;
 run;

 proc sgplot data=EvalHistory;
    title "Tune tSne with GA on Iris Data";
    scatter x=Evaluation y=tSNEKLLoss / group=Iteration;
    series x=Evaluation y=default /
       curvelabel="default" lineattrs=(pattern=shortdash);
    series x=Evaluation y=best /
       curvelabel="best" lineattrs=(color=green pattern=shortdash);
 run;

 proc sgplot data=IterHistory;
    title "Tune tSne with GA on Iris Data";
    series x=Iteration y=Best_Obj;
    series x=Iteration y=Time_Sec / y2axis;
 run;

Output 7.18.1 shows the "Tuner Information" output table, which displays the values of parameters that the tuner used.

Output 7.18.2 shows the "Tuner Results" output table, which displays the default configuration (Evaluation 0) and up to 10 of the best configurations that the tuner found. For each configuration, the hyperparameter values and objective value are provided.

Output 7.18.3 shows the "Tuner Iteration History" output table, which displays the results of each iteration. For each iteration, the number of evaluations, the best objective value so far, and the tuning time in seconds are provided.

Output 7.18.4 shows the "Tuner Evaluation History" output table, which displays all model configurations that the tuner evaluated. For each configuration, the hyperparameter values and objective value are provided.

Output 7.18.5 shows the "Best Configuration" output table, which displays the values of hyperparameters and the objective value for the best configuration that the tuner found.

Output 7.18.6 shows the "Tuner Summary" output table, which displays statistics about the tuning process.

Output 7.18.7 shows the "Tuner Task Timing" output table, which displays timing information about the different tasks that were performed during the tuning process.

Output 7.18.8 shows the "Output CAS Tables" output table, which displays a list of CAS tables that were created during the tuning process.

Output 7.18.9 shows the "Hyperparameter Importance" output table, which displays the relative importance of each hyperparameter during the tuning process, normalized by the effect of the most influential hyperparameter (importance set to 1) and listed in order of decreasing effect.

The first PROC SGPLOT step creates a scatter plot of the objective value (Kullback-Leibler loss in this case) evaluation history by iteration, which is shown in Output 7.18.10. The second PROC SGPLOT step creates a line plot of the best objective value by iteration and a line plot of the total tuning time by iteration, which are shown in Output 7.18.11.

s:loadtable{casLib="casuser", path="iris.csv"}

result = s:autotune_tuneTsne {
   trainOptions     = {
      table         = {name='iris'},
      inputs        = {"SepalLength", "SepalWidth", "PetalLength", "PetalWidth"},
      nDimensions   = 2,
      perplexity    = 5,
      learningRate  = 100,
      maxIters      = 500,
      output        = {casOut={name="tsne_out", replace="TRUE"},
                       copyvars={"id", "species"}}
   },
   tunerOptions     = {
      searchMethod  = "GA",
      popSize       = 10,
      logLevel      = 3,
      seed          = 12345
   }
   --[[ Tuning Parameters

     You do not need to specify any tuning parameters for the default
     tuning process. If you want to make adjustments to the default
     tuning process, uncomment the following block of code and change
     any of the tuning parameters' attributes.

   , tuningParameters = {
      {name="perplexity",   initValue=30,   lb=5,   ub=50,    exclude=false},
      {name="learningRate", initValue=1000, lb=10,  ub=2000,  exclude=false},
      {name="maxIters",     initValue=300,  lb=250, ub=5000,  exclude=false}
  }
  --]]

}

print(result.TunerInfo)
print(result.TunerResults)
print(result.IterationHistory)
print(result.EvaluationHistory)
print(result.BestConfiguration)
print(result.TunerSummary)
print(result.TunerTiming)
print(result.TunerCasOutputTables)
print(result.HyperparameterImportance)

s.upload_file('iris.csv')

result = s.autotune.tuneTsne (
   trainOptions      = {
      "table"        : {"name":"iris"},
      "inputs"       : {"SepalLength", "SepalWidth", "PetalLength", "PetalWidth"},
      "nDimensions"  : 2,
      "perplexity"   : 5,
      "learningRate" : 100,
      "maxIters"     : 500,
      "output"       : {"casOut":{"name":"tsne_out", "replace":"TRUE"},
                        "copyvars":{"id", "species"}}
   },
   tunerOptions      = {
      "searchMethod" : "GA",
      "popSize"      : 10,
      "logLevel"     : 3,
      "seed"         : 12345
   }
   # Tuning Parameters
   #
   # You do not need to specify any tuning parameters for the default
   # tuning process. If you want to make adjustments to the default
   # tuning process, uncomment the following block of code and change
   # any of the tuning parameters' attributes.
   #
   # , tuningParameters = [
   #    {"name":"perplexity",
   #       "initValue":30,   "lb":5,   "ub":50,    "exclude":"false"},
   #    {"name":"learningRate",
   #       "initValue":1000, "lb":10,  "ub":2000,  "exclude":"false"},
   #    {"name":"maxIters",
   #       "initValue":300,  "lb":250, "ub":5000,  "exclude":"false"}
   # ]

)

print(result.TunerInfo)
print(result.TunerResults)
print(result.IterationHistory)
print(result.EvaluationHistory)
print(result.BestConfiguration)
print(result.TunerSummary)
print(result.TunerTiming)
print(result.TunerCasOutputTables)
print(result.HyperparameterImportance)