SASEWBGO Interface Engine

(View the complete code for this example.)

This example demonstrates the use of the PER_PAGE= option inside the SAS macro named X.

options validvarname=any;

title 'Retrieve the Entire Range of Data Observations in One Page';
%macro x(per_page=);

%let i=&per_page;
%if &i<=50 %then %do;
    libname wbgo sasewbgo "%sysget(WBGO)"
       OUTXML=gdpMall
       AUTOMAP=replace
       MAPREF=MyMap
       XMLMAP="%sysget(WBGO)gdpMall.map"
       COUNTRYLIST='all'
       IDLIST='NY.GDP.PCAP.CD,NY.GDP.PCAP.KN,NY.GDP.PCAP.PP.KD'
       RANGE='2010:2016'
       PER_PAGE=&i
       PAGE=1;

   data mygdpMall;
      set wbgo.gdpMall;
   run;

   proc contents data=mygdpMall; run;
   proc print data=mygdpMall; run;

   proc sql noprint;
      select t.total_count into :allnobs
      from work.mygdpMall t;
   quit;

  %if &allnobs>50 %then %do;
    libname wbgo sasewbgo "%sysget(WBGO)"
       OUTXML=gdpTall
       AUTOMAP=replace
       MAPREF=MyMap
       XMLMAP="%sysget(WBGO)gdpTall.map"
       COUNTRYLIST='all'
       IDLIST='NY.GDP.PCAP.CD,NY.GDP.PCAP.KN,NY.GDP.PCAP.PP.KD'
       RANGE='2010:2016'
       PER_PAGE=&allnobs
       PAGE=1;

   data mygdpTall;
      set wbgo.gdpTall;
   run;
  %end;
%end;
%mend;

%x(per_page=50);  /* call the X macro with PER_PAGE=50 */

   proc contents data=mygdpTall; run;
   proc print data=mygdpTall(drop=total_count firstobs=1800 obs=1848); run;

Output 54.10.1 shows the results for all countries (ALL) listed in the COUNTRYLIST= option. Three time series are specified in the IDLIST= option. For the entire specified range, for years 2010–2016, the time series have a total of 1,848 observation values.

The X macro shows how to obtain the total observation count by first requesting only 50 observations (PER_PAGE=50, PAGE=1) in the first SASEWBGO LIBNAME statement. The SAS data set that the SASEWBGO engine creates is named GdpMall by the OUTXML= option in the first SASEWBGO LIBNAME statement. The PROC SQL SELECT statement stores the total number of observations from the SAS variable TOTAL_COUNT in the SAS macro variable named ALLNOBS. This allows the second SASEWBGO LIBNAME statement to use the total observation count in the PER_PAGE= option so that all 1,848 observations are downloaded in one page. The SAS data set gdpTall contains all 1,848 observations. For brevity, only the last 48 observations are shown in Output 54.10.1.